[Risolto] Incolonnare dati di una tabella

[claud]

Buona sera avrei bisogno di un aiuto per capire se è realizzabile, magari senza macro un idea:
Ho una griglia (A1:J10) nella quale sono inseriti dei numeri ottenuti tramite una formula,praticamente una sorta di battaglia navale, le celle in cui sono inseriti possono cambiare col variare dei dati di partenza.
Detto questo chiedo se sia possibile ottenere i dati incolonnati come nella tabella L1:N10.
Ringrazio chi mi potrà aiutare.
Claudio.

GRIGLIA.ods

(12.67 KiB) Scaricato 60 volte

[patel]

Con una macro è sicuramente possibile, senza non so, devi attendere un esperto formulaio.

[Lanfranchi G.Luigi]

Non ho idea se questa soluzione può andarti bene.
Le colonne con le formule le potrai poi gestire come più ti piace.
Potrai spostarle in un altro foglio (con i giusti riferimenti) o nasconderle.

[claud]

Complimenti per la realizzazione, va benissimo.
Grazie.
Claudio

[gioh66]

Ciao. Per gioco, visto che avete già risolto, e se hai una versione di libreoffice superiore o uguale a 7, si potrebbe semplificare l'ottimo lavoro di @Lanfranchi G.Luigi con due formule.
La prima per creare la colonna d'appoggio è

Codice: Seleziona tutto

=INDIRETTO(INDIRIZZO(RESTO(RIF.RIGA(A1)-1;10)+1;QUOZIENTE(RIF.RIGA(A1)-1;10)+1))

da tirare in basso per 100 righe
Poi per incolonnare come da tuo esempio, però senza colonna vuota in mezzo

Codice: Seleziona tutto

=SE.ERRORE(INDICE($Q$1:$Q$204;AGGREGA(15;6;RIF.RIGA($Q$1:$Q$204)/($Q$1:$Q$204<>0);RIF.RIGA(A1)+(10*(RIF.COLONNA(A1)-1))));"")

[claud]

Grazie Gioh66, la griglia come avevo inserito nel file era un esempio, in realtà andrebbe posizionata in AH1:AQ10 e non riesco a capire come andrebbero modificate le formule...scusami se approfitto.
Claudio

GRIGLIA (bis).ods

(15.6 KiB) Scaricato 53 volte

[gioh66]

Ciao. La formula per creare la colonna d'appoggio la modifichi così

Codice: Seleziona tutto

=INDIRETTO(INDIRIZZO(RESTO(RIF.RIGA(AH1)-1;10)+1;QUOZIENTE(RIF.RIGA(AH1)-1;10)+1))

Quella per estrarre le colonne così

Codice: Seleziona tutto

=SE.ERRORE(INDICE($AT$1:$AT$100;AGGREGA(15;6;RIF.RIGA($AT$1:$AT$100)/($AT$1:$AT$100<>0);RIF.RIGA(A1)+(10*(RIF.COLONNA(A1)-1))));"")

Questa formula vale se hai libreoffice uguale o superiore a 7.

GRIGLIA con AGGREGA 7+.ods

(20.1 KiB) Scaricato 47 volte

Se invece come da profilo hai una versione 6, allora ti serve ancora una colonna d'appoggio da creare con questa formula

Codice: Seleziona tutto

=SE(AT1>0;RIF.RIGA();"")

Con questa ricavi i numeri di riga in cui nella colonna a fianco il valore è maggiore di 0, e la formula per estrarre le colonne diventa

Codice: Seleziona tutto

=SE.ERRORE(INDICE($AT$1:$AT$100;AGGREGA(15;6;$AU$1:$AU$100;RIF.RIGA(A1)+(10*(RIF.COLONNA(A1)-1))));"")

GRIGLIA con AGGREGA pre 7.ods

(20.68 KiB) Scaricato 55 volte

Ti ho allegato i file con le due diverse soluzioni.

[Lanfranchi G.Luigi]

Ciao.
Ho visto che qualche cosa è sfuggito al collega gioh66 perchè i file che ha allegato non funzionano (a me per lo meno).
Cosi ho un po pasticciato scopiazzando dal primo file che gioh66 ti ha mandato facendo delle modifiche.
Premetto che le formule che gioh66 ha scritto le ho digerite a malapena...

Comunque questo a me funziona.
Ciao.

[gioh66]

Non so che dirti. Io ho provato a riscaricarli e funzionano. Che dipenda dalla versione di libre? Vedo che tu hai già la 7.5 mentre io lavoro con la 7.3.

[Lanfranchi G.Luigi]

Ciao.
Se cambi i valori nella tabella i valori nelle colonne non si aggiornano.
i file che hai mandato fanno riferimento ancora alla tabella "A1-J10".
Prova a cancellare i dati nell'area A1-j10 ...

[gioh66]

Cavolo hai ragione. Non avevo considerato lo spostamento della tabella . Per correggere cambia la formula per incolonnare i dati con

Codice: Seleziona tutto

=INDIRETTO(INDIRIZZO(RESTO(RIF.RIGA(AH1)-1;10)+1;QUOZIENTE(RIF.RIGA(AH1)-1;10)+1+RIF.COLONNA($AG$1)))

il resto rimane uguale.
Riallego i file con la correzione

[claud]

Siete strepitosi...grazie ad entrambi per la disponibilità.
Claudio